(*
(C) Hado Hein ,1998, Berlin, FRG
something for developers.
THIS A TOOL nothing for consumers. SO LEARN TO HANDLE IT.

You might have two system folders (with System Picker from Dev CD) on one volume. 
Very often you'll have to see what`s going on in the other System Folder (extensions and so on).
Instead of always digging from top, the script opens the other folder and arranges the windows for you.

*)
property sieben : "MacHD:System Folder (7.6):"
property acht : "MacHD:System Folder (8.1):"
property stringLib : load script "MacHD:AppleScript Samples:Libraries:stringLib"
-- stringLib is found on DevCD / ScriptSamples
tell application "Finder"
	
	set SelectList to (get every item in selection)
	set AktFolder to folder of (get first item in SelectList)
	set NewLoc to ""
	
	if AktFolder contains "System Folder (7.6):" then
		set destSystem to acht
	else if AktFolder contains "System Folder (8.1):" then
		set destSystem to sieben
	else
		return
	end if
	
	if (AktFolder as string) contains "Scripting Additions:" and destSystem = sieben then
		set NewLoc to (sieben & "Extensions:Scripting Additions:")
	else if (AktFolder as string) contains "Scripting Additions:" and destSystem = acht then
		set NewLoc to (acht & "Scripting Additions:")
	else -- set this bloody folder
		if kind of AktFolder is "folder" then
			set AktFolder to AktFolder -- now we have the folder including volume
		else
			set AktFolder to folder of AktFolder -- now we have the folder including volume
		end if
		set AktFolder to (getEnd of stringLib from (AktFolder as string) at "):") -- we strip off the pre run
		set NewLoc to destSystem & AktFolder
	end if
	
	open window of folder NewLoc
	
	repeat with I in (SelectList)
		set FileToSelect to (NewLoc & name of I)
		if (exists item FileToSelect) then
			set selected of item FileToSelect to true
		end if
	end repeat
	
	set srcWin to (bounds of window of folder of first item in SelectList) -- the folder where selection was
	set dstWin to (bounds of window of folder NewLoc) -- the folder where selection was set
	
	repeat with I in (list screens)
		if (item 1 of srcWin Ñ item 1 of bounds of I) and (item 1 of srcWin æ item 3 of bounds of I) then
			set schirm to bounds of I
		end if
	end repeat
	
	set ScrWid to (item 3 of schirm) - (item 1 of schirm)
	set ScrWid to ScrWid / 2 - 150 as integer
	
	set item 1 in srcWin to (item 1 of schirm) + 100
	set item 3 in srcWin to (item 1 of srcWin) + ScrWid
	set item 2 in srcWin to (item 2 of schirm) + 50
	set item 4 in srcWin to (item 4 of schirm) - 250
	
	set item 1 in dstWin to ((item 3 of srcWin) + 20)
	set item 3 in dstWin to ((item 1 of dstWin) + ScrWid)
	set item 2 in dstWin to (item 2 of schirm) + 50
	set item 4 in dstWin to (item 4 of schirm) - 250
	
	set bounds of window of folder of first item in SelectList to srcWin
	set bounds of window of folder NewLoc to dstWin
	
	
end tell